StyleProject, czyli wygląd OSX w Qt5/Plasma 5

[pavbaranov]

Jak na razie, pierwsza wersja, czyli tworząca wyłącznie styl dla aplikacji Qt5/Plasma 5 (do wyboru przez Ustawienia Systemowe). Niebawem będzie wersja umożliwiająca również wybór dla aplikacji Qt4/KDE4 i posługująca się wyłącznie kodem z GIT, a nie jego snapshotem.
PKGBUILD

Kod: [Zaznacz]

pkgname=styleproject
pkgver=0.1
pkgrel=1
pkgdesc='A maclike style for qt4/qt5/kde4/kde5'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/styleproject/'
license=('GPL' 'LGPL')
makedepends=('qt5-base' 'extra-cmake-modules' 'kcoreaddons' 'kconfigwidgets' 'kwindowsystem' 'kguiaddons')
source=("http://sourceforge.net/code-snapshots/git/s/st/styleproject/code.git/styleproject-code-9f34d02232e6ee645fb7d57b8c14877f54d13830.zip")
md5sums=('0cf4e417bd436e720607afddcdf5c42e')

prepare() {
   mkdir build-qt5
   mkdir styleproject
   mv $srcdir/styleproject-code-*/* $srcdir/styleproject/
   }

build() {
  cd build-qt5
  cmake ../${pkgbase} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT5BUILD=ON \
    -DLIB_INSTALL_DIR=lib
  make
}

package() {
  depends=('qt5-base' 'qt5-base' 'qt5-x11extras')

  cd build-qt5
  make DESTDIR="$pkgdir" install
}

[pavbaranov]

Styleproject wprawdzie nie udało mi się doprowadzić do splitowanego PKGBUILDa, niemniej jednak - znów dzięki Marcinowi udało mi się doprowadzić obie wersje do działających i koegzystujących w jednym systemie. Od teraz można zatem mieć ten styl zarówno dla aplikacji korzystających z Qt5, jak i Qt4. Być może wersję opartą o Qt5 doprowadzę jeszcze do postaci "czystego Qt5", albowiem obecna wersja oparta jest o KF5; podobnie z wersją Qt4, która jest oparta o KDE4, ale to się jeszcze okaże. Przede wszystkim jest to jednak zależne od Was: czy chcecie i potrzebujecie takiej wersji. Ja jej nie potrzebuję, albowiem i tak używam Plasma 5.

1. Wersja dla KDE4
PKGBUILD

Kod: [Zaznacz]

# Maintainer: pavbaranov
# Contributor: marcin82

pkgname=styleproject-kde4
_pkgname=styleproject
pkgver=0.1
pkgrel=1
pkgdesc='A maclike style for KDE4'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/styleproject/'
license=('GPL' 'LGPL')
depends=('kdelibs' 'qt5-x11extras')
makedepends=('git' 'cmake' 'automoc4')
optdepends=('styleproject-kf5: Plasma 5 version')
source=('http://sourceforge.net/code-snapshots/git/s/st/styleproject/code.git/styleproject-code-9f34d02232e6ee645fb7d57b8c14877f54d13830.zip')
md5sums=('0cf4e417bd436e720607afddcdf5c42e')

prepare() {
   mkdir build
   mkdir styleproject
   mv $srcdir/styleproject-code-*/* $srcdir/styleproject/
   sed -e 's|include/dsp|include/dsp-qt4|g' -i styleproject/config/CMakeLists.txt
   }

build() {
  cd build
  cmake ../${_pkgname} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT5BUILD=OFF \
    -DBUILD_TESTING=OFF\
    -DQT_QMAKE_EXECUTABLE=/usr/bin/qmake-qt4
  make
  }

package() {
  cd build
  make DESTDIR="$pkgdir" install
  }
2. Wersja dla Plasma 5:

Kod: [Zaznacz]

# Maintainer: pavbaranov
# Contributor: marcin82

pkgname=styleproject-kf5
_pkgname=styleproject
pkgver=0.1
pkgrel=1
pkgdesc='A maclike style for Plasma 5'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/styleproject/'
license=('GPL')
depends=('kwin' 'frameworkintegration')
makedepends=('git' 'extra-cmake-modules')
optdepends=('styleproject-kde4: Qt4 version')
source=('http://sourceforge.net/code-snapshots/git/s/st/styleproject/code.git/styleproject-code-9f34d02232e6ee645fb7d57b8c14877f54d13830.zip')
md5sums=('0cf4e417bd436e720607afddcdf5c42e')

prepare() {
   mkdir build
   mkdir styleproject
   mv $srcdir/styleproject-code-*/* $srcdir/styleproject/
   sed -e 's|include/dsp|include/dsp-qt5|g' -i styleproject/config/CMakeLists.txt
   }

build() {
  cd build
  cmake ../${_pkgname} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT5BUILD=ON \
    -DBUILD_TESTING=OFF\
    -DQT_QMAKE_EXECUTABLE=/usr/bin/qmake-qt5
  make
  }

package() {
  cd build
  make DESTDIR="$pkgdir" install
  }UWAGA: Jeśli ktoś zainstalował styleproject-qt5 i chciałby teraz (lub w przyszłości) zainstalować styleproject-kf5, to proszę wpierw odinstalować styleproject-qt5, albowiem  styleproject-kf5 jest w konflikcie (zamierzonym) z styleproject-qt5, choć dostarcza praktycznie to samo. Jak na razie nie będę rozwijać wersji Qt4/Qt5, a wobec powyższego jedyna na razie dostępna dla Qt5, to będzie KF5. Niemniej jednak zachowuję sobie "miejsce" na ewentualne wersje oparte o czyste Qt4 i/lub Qt5, a wówczas zadecyduję, czy wersja KF5 będzie w konflikcie z Qt5, czy też przeprowadzić ją bezkonfliktowo (inna sprawa, że obu w Plasma 5 sensu utrzymywania nie ma).

[pavbaranov]

Obecnie wersja dla KDE4 znajduje się w AUR - nie będzie zatem przeze mnie kontynuowana.

[pavbaranov]

Postanowiłem zmienić rozwój tej wersji na to, co w istocie dzieje się w jego repozytorium. Program jest rozwijany w sposób ciągły w GIT i autor - jak na razie - nie robi żadnego jego "wersjonowania". Stąd też decyzja o dalszym rozwoju, jako paczka *-git. Dla wersji Qt5 otrzymujemy następujący skrypt:
PKGBUILD

Kod: [Zaznacz]

# Maintainer: pavbaranov
# Contributor: marcin82

pkgname=styleproject-qt5-git
_gitname=code
pkgver=r357.6aeb907
pkgrel=1
pkgdesc='A maclike style for qt4/qt5/kde4/plasma5 - Plasma 5 version'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/styleproject/'
license=('GPL')
depends=('kwin' 'frameworkintegration')
makedepends=('git' 'extra-cmake-modules')
optdepends=('styleproject-qt4: Qt4 version')
conflicts=('styleproject-qt5')
source=('git+http://git.code.sf.net/p/styleproject/code')
md5sums=('SKIP')

pkgver() {
  cd "${_gitname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  }
 
prepare() {
   mkdir build
   sed -e 's|include/dsp|include/dsp-qt5|g' -i code/config/CMakeLists.txt
   }

build() {
  cd build
  cmake ../${_gitname} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT5BUILD=ON \
    -DBUILD_TESTING=OFF
  make
  }

package() {
  cd build
  make DESTDIR="$pkgdir" install
  }
Dla wersji Qt4 (tak, miała być niekontynuowana, ale zamieszczam wersję *-git):
PKGBUILD

Kod: [Zaznacz]

# Maintainer: pavbaranov
# Contributor: marcin82

pkgname=styleproject-qt4-git
_gitname=code
pkgver=r357.6aeb907
pkgrel=1
pkgdesc='A maclike style for qt4/qt5/kde4/plasma5 - KDE4 version'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/styleproject/'
license=('GPL')
depends=('kdelibs')
makedepends=('git' 'extra-cmake-modules')
optdepends=('styleproject-qt5: Qt4 version')
conflicts=('styleproject-qt4')
source=('git+http://git.code.sf.net/p/styleproject/code')
#source=('http://sourceforge.net/code-snapshots/git/s/st/styleproject/code.git/styleproject-code-6aeb907fcb05720ed0401ef2ed95caab90405889.zip')
md5sums=('SKIP')

pkgver() {
  cd "${_gitname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  }
 
prepare() {
   mkdir build
   sed -e 's|include/dsp|include/dsp-qt4|g' -i code/config/CMakeLists.txt
   }

build() {
  cd build
  cmake ../${_gitname} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT5BUILD=OFF \
    -DBUILD_TESTING=OFF
  make
  }

package() {
  cd build
  make DESTDIR="$pkgdir" install
  }